6. Sample program

'Here' is a sample program that you can run to see Gnome2::Druid in action.

	  
 #!/usr/bin/perl -w
 
 use strict;
 use Glib qw/TRUE FALSE/;
 use Gnome2;
 use Cwd;
 
 my $logo = Gtk2::Gdk::Pixbuf->new_from_file("./faces/soccerball.png");
 my $watermark = Gtk2::Gdk::Pixbuf->new_from_file("faces/penguin.jpg");
 my $top_watermark = Gtk2::Gdk::Pixbuf->new_from_file("faces/tennis-ball.png");
 
 my $page_one_text = 
 "A Druid has a 'Start' and 'Finish' screen. They are blessed references to the Gnome2::DruidPageEdge class. This class looks different from the Gnome2::DruidPageStandard class.\n\nThe 'Start' screen usually contains a simple message telling you what the Druid is about.\n\nThe 'Finish' screen usually thank you for taking it and offers a 'Commit' type of button.\n\nThe pages in between should be blessed references to the Gnome2::DruidPageStandard class. This class can contain more complex child classes. They are used to gather information from the user.\n\nGnome2::DruidPageStandard and Gnome2::DruidPageEdge are both sub classes of Gnome2::DruidPage.\n\nGnome2::DruidPage should never be created directly. It will implicitly be created when Gnome2::DruidPageStandard or Gnome2::DruidPageEdge gets created.";
 
 my $end_page_text = 
 "Thank you for taking this Druid!. We trust that you now know a bit more about Gnome2::Druid and the classes used with it.";
 
 Gnome2::Program->init ('DruidTest', '1.0beta', 'libgnomeui');
 
 
 #returns a druid and a window
 my ($druid, $window) = Gnome2::Druid->new_with_window ("Gnome2 Druid Tutorial", undef, TRUE);
 
 #this will set the label on the finish button to "Finish", default is "Apply"
 $druid->finish->set_label ("_Finish");
 
 #When we click the "Finish" button, we exit
 $druid->finish->signal_connect (clicked => sub { Gtk2->main_quit ; 1 });
 
 #PAGES:
 #Pages gets added to the druid, you start and end with a Gnome::DruidPageEdge
 #the rest should be Gnome2::DruidPageStandard pages.
 
 	#--------------------------
 	# START PAGE
 	#--------------------------
 	my $druid_page_start = Gnome2::DruidPageEdge->new_with_vals ('start', FALSE,
 		"Welcome to the Druid Start Page",
 		$page_one_text,
 		$logo,
 		$watermark,
 		$top_watermark);
 
 	#Connect to the 'next' signal to do error checking
 	$druid_page_start->signal_connect('next' => sub { 
 	
 		my $retval = &show_message_dialog($window,'question',"This does a check, continue?",'yes-no');
 		warn $retval."\n";
 		#If the return value is boolean TRUE, the event signal will be stopped from propagating,
 		# but if it is boolean FALSE, it will continue with the propagation of the signal
 
 		return FALSE if $retval =~ /yes/i;
 		return TRUE if $retval =~ /no/i;		
 	});
 
 #add the page to the druid
 $druid->append_page ($druid_page_start);
 
 #customize the page
 $druid_page_start->set_bg_color (Gtk2::Gdk::Color->new(60000,0,0));
 $druid_page_start->set_textbox_color (Gtk2::Gdk::Color->new(60000,60000,0));
 
 
 	#--------------------------
 	#Middle page:
 	#--------------------------
 	my $druid_page_middle = Gnome2::DruidPageStandard->new_with_vals ('Middle Standard Page', $logo, $top_watermark);
 
 	#convenience method - part of Gnome2::DruidPageStandard
 	$druid_page_middle->append_item ('Do you like sport?', Gtk2::CheckButton->new('Yes'), '(click if you do)');
 
 #add the page to the druid
 $druid->append_page ($druid_page_middle);
 
 
 	#--------------------------
 	#End Page:
 	#--------------------------
 	#this shows the default values
 	my $druid_page_end = Gnome2::DruidPageEdge->new_with_vals ('finish', FALSE,
 		"Goodbye",
 		$end_page_text,
 		undef,
 		undef,
 		undef);
 
 #add the page to the druid
 $druid->append_page ($druid_page_end);
 
 $window->set_position('center-always');
 
 $window->show_all;
 $window->signal_connect (destroy => sub { Gtk2->main_quit; 1 });
 
 Gtk2->main;
 
 #_____________________________________________________
 
 
 sub show_message_dialog {
 
 #you tell it what to display, and how to display it
 #$parent is the parent window, or "undef"
 #$icon can be one of the following:	a) 'info'
 #					b) 'warning'
 #					c) 'error'
 #					d) 'question'
 #$text can be pango markup text, or just plain text, IE the message
 #$button_type can be one of the following: 	a) 'none'
 #						b) 'ok'
 #						c) 'close'
 #						d) 'cancel'
 #						e) 'yes-no'
 #						f) 'ok-cancel'
 
 my ($parent,$icon,$text,$button_type) = @_;
   
 my $dialog = Gtk2::MessageDialog->new_with_markup ($parent,
 					[qw/modal destroy-with-parent/],
 					$icon,
 					$button_type,
 					sprintf "$text");						
 	my $retval = $dialog->run;
 	$dialog->destroy;
 	return $retval;
 }